fivedev/harbour-core
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
175f05df5637ea76c0c32a0d4b2ed2ff7bc541c8
harbour-core/harbour/src/rtl/tclass.prg
Viktor Szakats 175f05df56 2013-02-26 14:41 UTC+0100 Viktor Szakats (harbour syenar.net) 
* utils/hbmk2/hbmk2.*.po
  * utils/hbmk2/hbmk2.prg
    + do not share plugin variables (hbmk[ "vars" ])
      between different plugins. It avoids potentially nasty
      issues with plugins stepping onto each other's toes.
      [INCOMPATIBLE - though it's unlikely anyone is
      affected. If you must communicate between plugins,
      use public function or variable.]
    + clarified in help that -icon might not work on all
      platforms/compilers and detailed Windows implementation
      (in particular it's disabled on bcc/bcc64 and on
      mingw it won't work when a manual .rc is specified,
      also on some (old?) msvc versions. Consult your
      C compiler's Windows resource handling limitations.)
    + clarified in help the syntax of filters
    + clarified in help that .hbp references are handled as
      sub-projects
    + clarification to command substitution macro
    + clarification to filter syntax note
    ! strict parameter checks in all public shell APIs to
      avoid RTEs inside hbmk2 due to faulty API usage by scripts

  * utils/hbmk2/examples/plug_bis.hb
    * updated according to latest plugin changes

  * include/harbour.hbx
  * include/hbapi.h
  * src/vm/debug.c
  * src/vm/hvm.c
    + added internal function hb_vmInternalsEnabled()
      to query whether potentially sensitive internals
      are allowed to be accessed by public Harbour APIs
    + added .prg level function __vmNoInternals()
      to disable potentially sensitive internals
      by default accessible via public APIs.
      Intentionally a one-way function: once disabled,
      it cannot be reenabled from .prg or .c level.
      NOTE: It will break Harbour debug functionality,
      so it'd will be useful for hbrun scripts and
      release (non-debug) builds.
    + modified internal __dbg*() functions to return
      dummy values when internals are disabled via
      __vmNoInternals() functions. While the function
      return types are kept, apps relying on their
      specific values and certain relationships between
      them might break.
    ; NOTE: In the future, some more internals might
      be protected by this setting (f.e. low-level
      object and class functions and some API from
      hbdebug lib)
    ; Please review

  * tests/debugtst.prg
    ! fixed to compile warning-free without lowering
      warning level
    ! fixed to run RTE-free with internals disabled

  * bin/3rdpatch.hb
  * bin/commit.hb
  * config/postinst.hb
  * contrib/make.hb
  * contrib/hbtest/hbtest.ch
  * src/debug/*.prg
  * src/rtl/tclass.prg
  * utils/hbmk2/examples/plug_bis.hb
  * utils/hbmk2/examples/plug_tpl.hb
    * use short form #pragmas (the ones identical
      to Harbour options)
    ; NOTE: Except -l which works reversed compared
      to cmdline -l option. TOFIX? (I tried and failed)

  * src/rtl/hbi18n2.prg
  * contrib/xhb/tfile.prg
    * use F_ERROR instead of -1 literal

  * contrib/xhb/xhbtedit.prg
    ! replaced dirty xhb extension with std SubStr() call
      Reported by Tony Quick
      [pls report such bugs on Harbour devl list]

  * contrib/hbodbc/todbc.prg
    ! Don't continue ::Open() when SQLExecDir() have error
      Fix from xhb via Vicente Guerra, with cleanups.

  * tests/multifnc/multifnc.hbp
    + added comment
    + support for watcom

  * tests/multifnc/t1.prg
    ! missing file ending EOL

  * tests/*.prg
  * extras/gtwvw/tests/wvwtest9.prg
    * formatting
2013-02-26 13:44:10 +00:00

481 lines
16 KiB
Plaintext
Raw Blame History

/*
* $Id$
*/
/*
* Harbour Project source code:
* Base Class for internal handling of class creation
*
* Copyright 1999 Antonio Linares <alinares@fivetech.com>
* www - http://harbour-project.org
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2, or (at your option)
* any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this software; see the file COPYING.txt. If not, write to
* the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
* Boston, MA 02111-1307 USA (or visit the web site http://www.gnu.org/).
*
* As a special exception, the Harbour Project gives permission for
* additional uses of the text contained in its release of Harbour.
*
* The exception is that, if you link the Harbour libraries with other
* files to produce an executable, this does not by itself cause the
* resulting executable to be covered by the GNU General Public License.
* Your use of that executable is in no way restricted on account of
* linking the Harbour library code into it.
*
* This exception does not however invalidate any other reasons why
* the executable file might be covered by the GNU General Public License.
*
* This exception applies only to the code released by the Harbour
* Project under the name Harbour. If you copy code from other
* Harbour Project or Free Software Foundation releases into a copy of
* Harbour, as the General Public License permits, the exception does
* not apply to the code that you add in this way. To avoid misleading
* anyone as to the status of such modified files, you must delete
* this exception notice from them.
*
* If you write modifications of your own for Harbour, it is your choice
* whether to permit this exception to apply to your modifications.
* If you do not wish that, delete this exception notice.
*
*/
/*
* The following parts are Copyright of the individual authors.
* www - http://harbour-project.org
*
* Copyright 2000 J. Lefebvre <jfl@mafact.com> and RA. Cuylen <rac@mafact.com>
* Multiple inheritance
* Support shared class DATA
* scoping (hidden, protected, readOnly)
* Use of __cls_param function to allow multiple superclass declaration
* Suppress of SetType and SetInit not more nedded
* Delegation and forwarding
* Preparing the InitClass class method (not working !!)
*
* Copyright 1999 Eddie Runia <eddie@runia.com>
* Support for inheritance
* Support for default DATA values
*
* See COPYING.txt for licensing terms.
*
*/
/* NOTE: This .prg is also used by the debugger subsystem,
therefore we need this switch to avoid an infinite
loop when launching it. [vszakats] */
#pragma -b-
/* Harbour Class HBClass to build classes */
#include "hboo.ch"
REQUEST HBObject
FUNCTION HBClass()
STATIC s_hClass /* NOTE: Automatically defaults to NIL */
LOCAL hClass
IF s_hClass == NIL .AND. __clsLockDef( @s_hClass )
BEGIN SEQUENCE
#if 0
hClass := __clsNew( "HBCLASS", 17,, @HBClass() )
#else
hClass := __clsNew( "HBCLASS", 16,, @HBClass() )
#endif
__clsAddMsg( hClass, "New" , @New() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "Create" , @Create() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddData" , @AddData() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddMultiData" , @AddMultiData() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddClassData" , @AddClassData() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddMultiClsData", @AddMultiClsData(), HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddInline" , @AddInline() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddMethod" , @AddMethod() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddClsMethod" , @AddClsMethod() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddVirtual" , @AddVirtual() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddDelegate" , @AddDelegate() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddFriendFunc" , @AddFriendFunc() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddFriendClass" , @AddFriendClass() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "Instance" , @Instance() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "SetOnError" , @SetOnError() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "SetDestructor" , @SetDestructor() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "InitClass" , @InitClass() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "cSuper" , {| Self | iif( Empty( ::asSuper ), NIL, ::asSuper[ 1 ]:name ) }, HB_OO_MSG_INLINE )
__clsAddMsg( hClass, "hClass" , 1, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_hClass" , 1, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "cName" , 2, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_cName" , 2, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aDatas" , 3, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aDatas" , 3, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aMethods" , 4, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aMethods" , 4, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aClsDatas" , 5, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aClsDatas" , 5, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aClsMethods" , 6, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aClsMethods" , 6, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aInlines" , 7, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aInlines" , 7, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aVirtuals" , 8, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aVirtuals" , 8, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aDelegates" , 9, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aDelegates" , 9, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "asSuper" , 10, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_asSuper" , 10, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "sOnError" , 11, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_sOnError" , 11, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "sDestructor" , 12, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_sDestructor" , 12, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "lModFriendly" , 13, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_lModFriendly" , 13, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "asFriendClass" , 14, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_asFriendClass" , 14, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "asFriendFunc" , 15, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_asFriendFunc" , 15, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "sClassFunc" , 16, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_sClassFunc" , 16, HB_OO_MSG_ASSIGN )
#if 0
__clsAddMsg( hClass, "class" , 17, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_class" , 17, HB_OO_MSG_ASSIGN )
#endif
ALWAYS
__clsUnlockDef( @s_hClass, hClass )
END SEQUENCE
ENDIF
RETURN __clsInst( s_hClass )
/* xSuper is used here as the new preprocessor file (hbclass.ch) send here
always an array (if no superclass, this will be an empty one)
In case of direct class creation (without the help of preprocessor) xSuper can be
either NIL or contain the name of the superclass. */
STATIC FUNCTION New( cClassName, xSuper, sClassFunc, lModuleFriendly )
LOCAL Self := QSelf()
LOCAL i
hb_default( @lModuleFriendly, .F. )
IF HB_ISSYMBOL( xSuper )
::asSuper := { xSuper }
ELSEIF Empty( xSuper )
::asSuper := {}
ELSEIF HB_ISSTRING( xSuper )
::asSuper := { __dynSN2Sym( xSuper ) }
ELSEIF HB_ISARRAY( xSuper )
::asSuper := {}
FOR EACH i IN xSuper
IF HB_ISSYMBOL( i )
AAdd( ::asSuper, i )
ELSEIF HB_ISSTRING( i ) .AND. ! Empty( i )
AAdd( ::asSuper, __dynSN2Sym( i ) )
ENDIF
NEXT
ENDIF
::cName := hb_asciiUpper( cClassName )
::sClassFunc := sClassFunc
::lModFriendly := lModuleFriendly
::aDatas := {}
::aMethods := {}
::aClsDatas := {}
::aClsMethods := {}
::aInlines := {}
::aVirtuals := {}
::aDelegates := {}
::asFriendClass := {}
::asFriendFunc := {}
RETURN QSelf()
STATIC PROCEDURE Create( /* MetaClass */ )
LOCAL Self := QSelf()
LOCAL n
LOCAL nClassBegin
LOCAL hClass
LOCAL ahSuper := {}
#if 0
Self:Class := MetaClass
#endif
FOR EACH n IN ::asSuper
hClass := __clsInstSuper( n ) /* Super handle available */
IF hClass != 0
AAdd( ahSuper, hClass )
ENDIF
NEXT
hClass := __clsNew( ::cName, Len( ::aDatas ), ahSuper, ::sClassFunc, ::lModFriendly )
::hClass := hClass
IF ! Empty( ahSuper )
IF ahSuper[ 1 ] != 0
__clsAddMsg( hClass, "SUPER" , 0, HB_OO_MSG_SUPER, ahSuper[ 1 ], HB_OO_CLSTP_EXPORTED + HB_OO_CLSTP_NONVIRTUAL )
__clsAddMsg( hClass, "__SUPER", 0, HB_OO_MSG_SUPER, ahSuper[ 1 ], HB_OO_CLSTP_EXPORTED + HB_OO_CLSTP_NONVIRTUAL )
ENDIF
ENDIF
__clsAddMsg( hClass, "REALCLASS", 0, HB_OO_MSG_REALCLASS, 0, HB_OO_CLSTP_EXPORTED )
#if 0
// We will work here on the MetaClass object to add the Class Method
// as needed
FOR EACH n IN ::aClsMethods
// do it
NEXT
#endif
/* local messages... */
FOR EACH n IN ::aDatas
__clsAddMsg( hClass, n[ HB_OO_DATA_SYMBOL ] , n:__enumIndex(), ;
HB_OO_MSG_ACCESS, n[ HB_OO_DATA_VALUE ], n[ HB_OO_DATA_SCOPE ] )
__clsAddMsg( hClass, "_" + n[ HB_OO_DATA_SYMBOL ] , n:__enumIndex(), ;
HB_OO_MSG_ASSIGN, n[ HB_OO_DATA_TYPE ] , n[ HB_OO_DATA_SCOPE ] )
NEXT
FOR EACH n IN ::aMethods
__clsAddMsg( hClass, n[ HB_OO_MTHD_SYMBOL ], n[ HB_OO_MTHD_PFUNCTION ],;
HB_OO_MSG_METHOD, NIL, n[ HB_OO_MTHD_SCOPE ] )
NEXT
nClassBegin := __cls_CntClsData( hClass )
FOR EACH n IN ::aClsDatas
__clsAddMsg( hClass, n[ HB_OO_CLSD_SYMBOL ] , n:__enumIndex() + nClassBegin,;
HB_OO_MSG_CLSACCESS, n[ HB_OO_CLSD_VALUE ], n[ HB_OO_CLSD_SCOPE ] )
__clsAddMsg( hClass, "_" + n[ HB_OO_CLSD_SYMBOL ], n:__enumIndex() + nClassBegin,;
HB_OO_MSG_CLSASSIGN, , n[ HB_OO_CLSD_SCOPE ] )
NEXT
FOR EACH n IN ::aInlines
__clsAddMsg( hClass, n[ HB_OO_MTHD_SYMBOL ], n[ HB_OO_MTHD_PFUNCTION ],;
HB_OO_MSG_INLINE, NIL, n[ HB_OO_MTHD_SCOPE ] )
NEXT
FOR EACH n IN ::aVirtuals
__clsAddMsg( hClass, n, n:__enumIndex(), HB_OO_MSG_VIRTUAL )
NEXT
FOR EACH n IN ::aDelegates
__clsAddMsg( ::hClass, n[ HB_OO_DELEG_SYMBOL ], n[ HB_OO_DELEG_MESSAGE ], ;
HB_OO_MSG_DELEGATE, n[ HB_OO_DELEG_OBJECT ], ;
n[ HB_OO_DELEG_SCOPE ] )
NEXT
IF ::sOnError != NIL
__clsAddMsg( hClass, "__OnError", ::sOnError, HB_OO_MSG_ONERROR )
ENDIF
IF ::sDestructor != NIL
__clsAddMsg( hClass, "__Destructor", ::sDestructor, HB_OO_MSG_DESTRUCTOR )
ENDIF
/* Friend Classes */
FOR EACH n IN ::asFriendClass
__clsAddFriend( ::hClass, n )
NEXT
/* Friend Functions */
FOR EACH n IN ::asFriendFunc
__clsAddFriend( ::hClass, n )
NEXT
RETURN
STATIC FUNCTION Instance()
LOCAL Self := QSelf()
RETURN __clsInst( ::hClass )
STATIC PROCEDURE AddData( cData, xInit, cType, nScope, lNoinit )
hb_default( @lNoInit, .F. )
hb_default( @nScope, HB_OO_CLSTP_EXPORTED )
/* Default Init for Logical and numeric */
IF ! lNoInit .AND. cType != NIL .AND. xInit == NIL
SWITCH Asc( cType )
CASE Asc( "L" ) /* Logical */
CASE Asc( "l" ) /* Logical */
xInit := .F.
EXIT
CASE Asc( "I" ) /* Numeric or Integer */
CASE Asc( "i" ) /* Numeric or Integer */
CASE Asc( "N" ) /* Numeric or Integer */
CASE Asc( "n" ) /* Numeric or Integer */
xInit := 0
EXIT
CASE Asc( "D" ) /* Date */
CASE Asc( "d" ) /* Date */
xInit := hb_SToD()
EXIT
CASE Asc( "T" ) /* Timestamp */
CASE Asc( "t" ) /* Timestamp */
xInit := hb_SToT()
EXIT
ENDSWITCH
ENDIF
AAdd( QSelf():aDatas, { cData, xInit, cType, nScope } )
RETURN
STATIC PROCEDURE AddMultiData( cType, xInit, nScope, aData, lNoInit )
LOCAL cData
FOR EACH cData IN aData
IF HB_ISSTRING( cData )
QSelf():AddData( cData, xInit, cType, nScope, lNoInit )
ENDIF
NEXT
RETURN
STATIC PROCEDURE AddClassData( cData, xInit, cType, nScope, lNoInit )
hb_default( @lNoInit, .F. )
hb_default( @nScope, HB_OO_CLSTP_EXPORTED )
nScope := hb_bitOr( nScope, HB_OO_CLSTP_CLASS )
/* Default Init for Logical and numeric */
IF ! lNoInit .AND. cType != NIL .AND. xInit == NIL
SWITCH Asc( cType )
CASE Asc( "L" ) /* Logical */
CASE Asc( "l" ) /* Logical */
xInit := .F.
EXIT
CASE Asc( "I" ) /* Numeric or Integer */
CASE Asc( "i" ) /* Numeric or Integer */
CASE Asc( "N" ) /* Numeric or Integer */
CASE Asc( "n" ) /* Numeric or Integer */
xInit := 0
EXIT
CASE Asc( "D" ) /* Date */
CASE Asc( "d" ) /* Date */
xInit := hb_SToD()
EXIT
CASE Asc( "T" ) /* Timestamp */
CASE Asc( "t" ) /* Timestamp */
xInit := hb_SToT()
EXIT
ENDSWITCH
ENDIF
AAdd( QSelf():aClsDatas, { cData, xInit, cType, nScope } )
RETURN
STATIC PROCEDURE AddMultiClsData( cType, xInit, nScope, aData, lNoInit )
LOCAL cData
FOR EACH cData IN aData
IF HB_ISSTRING( cData )
QSelf():AddClassData( cData, xInit, cType, nScope, lNoInit )
ENDIF
NEXT
RETURN
STATIC PROCEDURE AddInline( cMethod, bCode, nScope )
hb_default( @nScope, HB_OO_CLSTP_EXPORTED )
AAdd( QSelf():aInlines, { cMethod, bCode, nScope } )
RETURN
STATIC PROCEDURE AddMethod( cMethod, sFuncSym, nScope )
hb_default( @nScope, HB_OO_CLSTP_EXPORTED )
AAdd( QSelf():aMethods, { cMethod, sFuncSym, nScope } )
RETURN
STATIC PROCEDURE AddClsMethod( cMethod, sFuncSym, nScope )
hb_default( @nScope, HB_OO_CLSTP_EXPORTED )
nScope := hb_bitOr( nScope, HB_OO_CLSTP_CLASS )
AAdd( QSelf():aClsMethods, { cMethod, sFuncSym, nScope } )
RETURN
STATIC PROCEDURE AddVirtual( cMethod )
AAdd( QSelf():aVirtuals, cMethod )
RETURN
STATIC PROCEDURE AddDelegate( xMethod, cDelegMsg, cObject, nScope )
LOCAL mth
IF HB_ISSTRING( xMethod )
AAdd( QSelf():aDelegates, { xMethod, cDelegMsg, cObject, nScope } )
ELSEIF HB_ISARRAY( xMethod )
FOR EACH mth IN xMethod
AAdd( QSelf():aDelegates, { mth, cDelegMsg, cObject, nScope } )
NEXT
ENDIF
RETURN
STATIC PROCEDURE AddFriendClass( ... )
LOCAL Self := QSelf()
AEval( hb_AParams(), {| sClass | AAdd( ::asFriendClass, sClass ) } )
RETURN
STATIC PROCEDURE AddFriendFunc( ... )
LOCAL Self := QSelf()
AEval( hb_AParams(), {| sFunc | AAdd( ::asFriendFunc, sFunc ) } )
RETURN
STATIC PROCEDURE SetOnError( sFuncPtr )
QSelf():sOnError := sFuncPtr
RETURN
STATIC PROCEDURE SetDestructor( sFuncPtr )
QSelf():sDestructor := sFuncPtr
RETURN
STATIC FUNCTION InitClass()
RETURN QSelf()
Reference in New Issue View Git Blame Copy Permalink