fivedev/harbour-core
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
a7e7b14b461f4430b1db5bc505a971b78d2cc3f5
harbour-core/src/rtl/tclass.prg
Przemysław Czerpak bc7ff4d5c6 2014-11-29 06:03 UTC+0100 Przemyslaw Czerpak (druzus/at/poczta.onet.pl) 
* include/hbapifs.h
  * src/common/hbffind.c
  * src/rtl/direct.c
  * src/rtl/dirscan.prg
  * src/rtl/filebuf.c
    + added lTime member to HB_FFIND structure
    + added 3-rd parmeter to hb_fsDirectory()
    + extended default maximum number of Harbour file IO redirecros to 128
    * use hb_xgrabz()
    * formatting

  * include/hbcompdf.h
  * include/hbpp.h
  * src/compiler/cmdcheck.c
  * src/compiler/genc.c
  * src/compiler/hbcomp.c
  * src/compiler/hbmain.c
  * src/compiler/ppcomp.c
  * src/pp/hbpp.c
  * src/pp/ppcore.c
  * src/pp/pplib.c
    + added support for -ql compiler switch - it disables displaying PRG line
      numbers during compilation
    + added internal support for switch which disables PRG names from final
      PCODE - it's not active by default

  * src/compiler/ppcomp.c
    + allow to change -gc? switch by #pragma directives

  * src/compiler/hbusage.c
    * present '-' as default option separator for all platforms

  * src/rdd/Makefile
  + src/rdd/rddshort.c
  - src/rdd/dbfuncs.prg
    * moved short function names (10 characters Cl*pper compatible) wrappers
      to rddshort.c

  * src/common/hbhash.c
  * src/compiler/gencc.c
  * src/compiler/hbcomp.c
  * src/compiler/hbdbginf.c
  * src/compiler/hbdead.c
  * src/compiler/hbmain.c
  * src/compiler/hbopt.c
  * src/debug/dbgentry.c
  * src/pp/ppcore.c
  * src/rdd/dbf1.c
  * src/rdd/dbfntx/dbfntx1.c
  * src/rdd/delim1.c
  * src/rdd/sdf1.c
  * src/rdd/hsx/hsx.c
  * src/rdd/usrrdd/usrrdd.c
  * src/rdd/wafunc.c
  * src/rdd/workarea.c
  * src/vm/classes.c
  * src/vm/dynsym.c
  * src/vm/estack.c
  * src/vm/runner.c
  * src/vm/set.c
  * src/vm/task.c
  * src/rtl/cdpapi.c
  * src/rtl/filebuf.c
  * src/rtl/gtcgi/gtcgi.c
  * src/rtl/gtcrs/gtcrs.c
  * src/rtl/gtstd/gtstd.c
  * src/rtl/gttrm/gttrm.c
  * src/rtl/gtxwc/gtxwc.c
  * src/rtl/hbdyn.c
  * src/rtl/hbgtcore.c
  * src/rtl/hbi18n1.c
  * src/rtl/hblpp.c
  * src/rtl/hbznet.c
  * src/rtl/iousr.c
    * use hb_xgrabz()

  * src/common/hbprintf.c
    * formatting
    * reduced variable scope

  * src/rdd/dblist.prg
  * src/rdd/hbsix/sxini.prg
  * src/rtl/hbfilehi.prg
    % use new hb_FName*() functions

  * src/codepage/cp_950.c
  * src/codepage/cp_big5.c
  * src/codepage/cp_gbk.c
  * src/codepage/cp_u16le.c
  * src/codepage/cp_utf8.c
  * src/common/hbfopen.c
  * src/common/hbstr.c
  * src/common/strwild.c
  * src/compiler/complex.c
  * src/compiler/genc.c
  * src/compiler/hbopt.c
  * src/compiler/hbusage.c
  * src/debug/dbghelp.prg
  * src/debug/debugger.prg
  * src/hbextern/hbextern.prg
  * src/main/harbour.1
  * src/pp/ppcore.c
  * src/rdd/dbcmd.c
  * src/rdd/dbcmd53.c
  * src/rdd/dbf1.c
  * src/rdd/dbfcdx/dbfcdx1.c
  * src/rdd/dbfntx/dbfntx1.c
  * src/rdd/dbjoin.prg
  * src/rdd/dbnubs.c
  * src/rdd/dbsort.prg
  * src/rdd/dbstrux.prg
  * src/rdd/dbtotal.prg
  * src/rdd/dbupdat.prg
  * src/rdd/hbsix/sxcompat.prg
  * src/rdd/hbsix/sxcrypt.c
  * src/rdd/hbsix/sxini.prg
  * src/rdd/hsx/hsx.c
  * src/rdd/usrrdd/usrrdd.c
  * src/vm/debug.c
  * src/vm/estack.c
  * src/vm/set.c
  * src/vm/task.c
  * src/rtl/achoice.prg
  * src/rtl/adir.prg
  * src/rtl/alert.prg
  * src/rtl/altd.prg
  * src/rtl/base64d.c
  * src/rtl/browse.prg
  * src/rtl/cdpapi.c
  * src/rtl/checkbox.prg
  * src/rtl/color53.prg
  * src/rtl/dbedit.prg
  * src/rtl/dircmd.prg
  * src/rtl/dirscan.prg
  * src/rtl/errapi.c
  * src/rtl/errsys.prg
  * src/rtl/fnsplit.c
  * src/rtl/gtchrmap.c
  * src/rtl/gtcrs/gtcrs.c
  * src/rtl/gtsln/gtsln.c
  * src/rtl/gtsln/mousesln.c
  * src/rtl/gttrm/gttrm.c
  * src/rtl/gtwin/gtwin.c
  * src/rtl/gtwvt/gtwvt.c
  * src/rtl/gtxwc/gtxwc.c
  * src/rtl/gui.prg
  * src/rtl/hbbfish.c
  * src/rtl/hbdoc.prg
  * src/rtl/hbfilehi.prg
  * src/rtl/hbgtcore.c
  * src/rtl/hbi18n2.prg
  * src/rtl/hbini.prg
  * src/rtl/hblpphb.c
  * src/rtl/hbregexc.c
  * src/rtl/memvarhb.prg
  * src/rtl/menusys.prg
  * src/rtl/menuto.prg
  * src/rtl/objfunc.prg
  * src/rtl/padc.c
  * src/rtl/padl.c
  * src/rtl/padr.c
  * src/rtl/profiler.prg
  * src/rtl/radiobtn.prg
  * src/rtl/radiogrp.prg
  * src/rtl/setcolor.c
  * src/rtl/tbcolumn.prg
  * src/rtl/tbrowse.prg
  * src/rtl/tclass.prg
  * src/rtl/tgetint.prg
  * src/rtl/tgetlist.prg
  * src/rtl/tmenusys.prg
  * src/rtl/tobject.prg
  * src/rtl/tpersist.prg
  * src/rtl/tpopup.prg
  * src/rtl/tpopuphb.prg
  * src/rtl/treport.prg
  * src/rtl/tscalar.prg
  * src/rtl/tsymbol.prg
  * src/rtl/ttextlin.prg
  * src/rtl/typefile.prg
    * formatting, casing, comment updating, removed trailing spaces, casting,
      replace hb_itemType() with HB_IS_*() macros, updated variable and
      function names and scopes, pacified unused result warnings, removed
      redundant castings, use HB_SIZEOFARRAY() and sizeof(), removed explicit
      NIL from parameters, use hb_LeftEq[I](), added supports for symbol items
      used as codeblock replacements, use hb_defaultValue(), use FOR EACH
      statement, use SWITCH statement, replaced SubStr() with Left() or
      Right(), use hb_AScan(), use hb_FReadLen()/hb_VFReadLen(),
      removed FO_READ from FOpen() parameters, use Str() instead of PadL(),
      use hb_StrShrink()

  * src/lang/l_el.c
  * src/lang/l_es_419.c
  * src/lang/l_fr.c
  * src/lang/l_hu.c
  * src/lang/l_pt_br.c
  * src/lang/l_sk.c
  * src/lang/l_tr.c
    * synced with Viktor's branch

  * src/rtl/achoice.prg
  * src/rtl/cdpdet.prg
    * synced with Viktor's branch

  * src/vm/Makefile
  + src/vm/short.c
    + added short function names (10 characters Cl*pper compatible) wrappers

  * src/vm/extrap.c
    * synced with Viktor's branch

  * src/rtl/Makefile
  + src/rtl/rtlshort.c
    + added short function names (10 characters Cl*pper compatible) wrappers

  * src/rtl/cdpdetc.c
  * include/harbour.hbx
    + added __wapi_GetConsoleOutputCP()

  * src/rtl/datec.c
  * include/harbour.hbx
    + added hb_CDay( <nDayOfWeek> ) -> <cDayName>

  * src/rtl/filesys.c
    ! do not check for PIPEs handles in WinCE builds
    ! respect OS returnb code in SystemTimeToFileTime()

  * src/rtl/gete.c
    * covered GetE() function by HB_CLP_UNDOC macro

  * src/rtl/philes53.c
    * covered FSetDevMod() function by HB_CLP_UNDOC macro

  * src/rtl/hbdoc.prg
    * use HB_SERIALIZE_COMPRESS instead of explicit hb_ZCompress()
      (incompatible, .hbd files has to be regenerated)

  * src/rtl/hbjson.c
    * add a newline at EOF in human readable mode

  * src/rtl/hbzlibgz.c
    * disabled GZIP support in MSVC WinCE builds

  * src/rtl/philes.c
  * include/harbour.hbx
    + added hb_FReadLen()

  * src/rtl/vfile.c
  * include/harbour.hbx
    + added hb_VFReadLen()

  * src/rtl/strclear.c
    ! check hb_itemGetWriteCL() result

  ; above modifications borrowed from Viktor's branch with some small
    modifications - many thanks

  * src/rtl/hbinet.c
    * extened readahead buffer from 256 to 1500 bytes
    ! fixed possible wrong result in hb_InetDataReady() and redirected
      sockets (i.e. by hb_InetCompress())

  * src/rtl/hbsocket.c
    ! typo in recent modification for BSD socket less builds

  + src/rtl/strutf8.c
  * include/harbour.hbx
    + added hb_StrIsUTF8() - it should be compatible with similar function
      from Viktor's branch

  * src/rtl/tpersist.prg
    * eliminated oSelf private variable and reduced macro expansion to
      item values

  * src/debug/dbgtmenu.prg
  * src/debug/dbgtwin.prg
  * src/debug/debugger.prg
    ! replaced SaveScreen()/RestScreen() with
      __dbgSaveScreen()/__dbgRestScreen() to fix problems with unicode
      characters which do not exists in HVM CP.

  * src/rdd/hbsix/sxcompat.prg
    + added support for timestamp values to sxChar(), sxNum(), sxDate()
      functions.
2014-11-29 06:03:17 +01:00

461 lines
16 KiB
Plaintext
Raw Blame History

/*
* Harbour Project source code:
* Base Class for internal handling of class creation
*
* Copyright 1999 Antonio Linares <alinares@fivetech.com>
* www - http://harbour-project.org
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2, or (at your option)
* any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this software; see the file COPYING.txt. If not, write to
* the Free Software Foundation, Inc., 59 Temple Place, Suite 330,
* Boston, MA 02111-1307 USA (or visit the web site http://www.gnu.org/).
*
* As a special exception, the Harbour Project gives permission for
* additional uses of the text contained in its release of Harbour.
*
* The exception is that, if you link the Harbour libraries with other
* files to produce an executable, this does not by itself cause the
* resulting executable to be covered by the GNU General Public License.
* Your use of that executable is in no way restricted on account of
* linking the Harbour library code into it.
*
* This exception does not however invalidate any other reasons why
* the executable file might be covered by the GNU General Public License.
*
* This exception applies only to the code released by the Harbour
* Project under the name Harbour. If you copy code from other
* Harbour Project or Free Software Foundation releases into a copy of
* Harbour, as the General Public License permits, the exception does
* not apply to the code that you add in this way. To avoid misleading
* anyone as to the status of such modified files, you must delete
* this exception notice from them.
*
* If you write modifications of your own for Harbour, it is your choice
* whether to permit this exception to apply to your modifications.
* If you do not wish that, delete this exception notice.
*
*/
/*
* The following parts are Copyright of the individual authors.
* www - http://harbour-project.org
*
* Copyright 2000 J. Lefebvre <jfl@mafact.com> and RA. Cuylen <rac@mafact.com>
* Multiple inheritance
* Support shared class DATA
* scoping (hidden, protected, readOnly)
* Use of __cls_param function to allow multiple superclass declaration
* Suppress of SetType and SetInit not more nedded
* Delegation and forwarding
* Preparing the InitClass class method (not working !!)
*
* Copyright 1999 Eddie Runia <eddie@runia.com>
* Support for inheritance
* Support for default DATA values
*
* See COPYING.txt for licensing terms.
*
*/
/* NOTE: This .prg is also used by the debugger subsystem,
therefore we need this switch to avoid an infinite
loop when launching it. [vszakats] */
#pragma -b-
/* Harbour Class HBClass to build classes */
#include "hboo.ch"
REQUEST HBObject
FUNCTION HBClass()
STATIC s_hClass /* NOTE: Automatically defaults to NIL */
LOCAL hClass
IF s_hClass == NIL .AND. __clsLockDef( @s_hClass )
BEGIN SEQUENCE
#if 0
hClass := __clsNew( "HBCLASS", 17,, @HBClass() )
#else
hClass := __clsNew( "HBCLASS", 16,, @HBClass() )
#endif
__clsAddMsg( hClass, "New" , @New() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "Create" , @Create() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddData" , @AddData() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddMultiData" , @AddMultiData() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddClassData" , @AddClassData() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddMultiClsData", @AddMultiClsData(), HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddInline" , @AddInline() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddMethod" , @AddMethod() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddClsMethod" , @AddClsMethod() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddVirtual" , @AddVirtual() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddDelegate" , @AddDelegate() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddFriendFunc" , @AddFriendFunc() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "AddFriendClass" , @AddFriendClass() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "Instance" , @Instance() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "SetOnError" , @SetOnError() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "SetDestructor" , @SetDestructor() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "InitClass" , @InitClass() , HB_OO_MSG_METHOD )
__clsAddMsg( hClass, "cSuper" , {| Self | iif( Empty( ::asSuper ), NIL, ::asSuper[ 1 ]:name ) }, HB_OO_MSG_INLINE )
__clsAddMsg( hClass, "hClass" , 1, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_hClass" , 1, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "cName" , 2, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_cName" , 2, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aDatas" , 3, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aDatas" , 3, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aMethods" , 4, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aMethods" , 4, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aClsDatas" , 5, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aClsDatas" , 5, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aClsMethods" , 6, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aClsMethods" , 6, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aInlines" , 7, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aInlines" , 7, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aVirtuals" , 8, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aVirtuals" , 8, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "aDelegates" , 9, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_aDelegates" , 9, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "asSuper" , 10, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_asSuper" , 10, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "sOnError" , 11, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_sOnError" , 11, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "sDestructor" , 12, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_sDestructor" , 12, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "lModFriendly" , 13, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_lModFriendly" , 13, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "asFriendClass" , 14, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_asFriendClass" , 14, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "asFriendFunc" , 15, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_asFriendFunc" , 15, HB_OO_MSG_ASSIGN )
__clsAddMsg( hClass, "sClassFunc" , 16, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_sClassFunc" , 16, HB_OO_MSG_ASSIGN )
#if 0
__clsAddMsg( hClass, "class" , 17, HB_OO_MSG_ACCESS )
__clsAddMsg( hClass, "_class" , 17, HB_OO_MSG_ASSIGN )
#endif
ALWAYS
__clsUnlockDef( @s_hClass, hClass )
END SEQUENCE
ENDIF
RETURN __clsInst( s_hClass )
/* xSuper is used here as the new preprocessor file (hbclass.ch) send here
always an array (if no superclass, this will be an empty one)
In case of direct class creation (without the help of preprocessor) xSuper can be
either NIL or contain the name of the superclass. */
STATIC FUNCTION New( cClassName, xSuper, sClassFunc, lModuleFriendly )
LOCAL Self := QSelf()
LOCAL i
IF HB_ISSYMBOL( xSuper )
::asSuper := { xSuper }
ELSEIF Empty( xSuper )
::asSuper := {}
ELSEIF HB_ISSTRING( xSuper )
::asSuper := { __dynsN2Sym( xSuper ) }
ELSEIF HB_ISARRAY( xSuper )
::asSuper := {}
FOR EACH i IN xSuper
IF HB_ISSYMBOL( i )
AAdd( ::asSuper, i )
ELSEIF HB_ISSTRING( i ) .AND. ! Empty( i )
AAdd( ::asSuper, __dynsN2Sym( i ) )
ENDIF
NEXT
ENDIF
::cName := hb_asciiUpper( cClassName )
::sClassFunc := sClassFunc
::lModFriendly := hb_defaultValue( lModuleFriendly, .F. )
::aDatas := {}
::aMethods := {}
::aClsDatas := {}
::aClsMethods := {}
::aInlines := {}
::aVirtuals := {}
::aDelegates := {}
::asFriendClass := {}
::asFriendFunc := {}
RETURN QSelf()
STATIC PROCEDURE Create( /* MetaClass */ )
LOCAL Self := QSelf()
LOCAL n
LOCAL nClassBegin
LOCAL hClass
LOCAL ahSuper := {}
#if 0
::Class := MetaClass
#endif
FOR EACH n IN ::asSuper
IF ( hClass := __clsInstSuper( n ) ) != 0 /* Super handle available */
AAdd( ahSuper, hClass )
ENDIF
NEXT
::hClass := hClass := __clsNew( ::cName, Len( ::aDatas ), ahSuper, ::sClassFunc, ::lModFriendly )
IF ! Empty( ahSuper ) .AND. ahSuper[ 1 ] != 0
__clsAddMsg( hClass, "SUPER" , 0, HB_OO_MSG_SUPER, ahSuper[ 1 ], HB_OO_CLSTP_EXPORTED + HB_OO_CLSTP_NONVIRTUAL )
__clsAddMsg( hClass, "__SUPER", 0, HB_OO_MSG_SUPER, ahSuper[ 1 ], HB_OO_CLSTP_EXPORTED + HB_OO_CLSTP_NONVIRTUAL )
ENDIF
__clsAddMsg( hClass, "REALCLASS", 0, HB_OO_MSG_REALCLASS, 0, HB_OO_CLSTP_EXPORTED )
#if 0
/* We will work here on the MetaClass object to add the Class Method
as needed */
FOR EACH n IN ::aClsMethods
// do it
NEXT
#endif
/* local messages... */
FOR EACH n IN ::aDatas
__clsAddMsg( hClass, n[ HB_OO_DATA_SYMBOL ] , n:__enumIndex(), ;
HB_OO_MSG_ACCESS, n[ HB_OO_DATA_VALUE ], n[ HB_OO_DATA_SCOPE ] )
__clsAddMsg( hClass, "_" + n[ HB_OO_DATA_SYMBOL ] , n:__enumIndex(), ;
HB_OO_MSG_ASSIGN, n[ HB_OO_DATA_TYPE ] , n[ HB_OO_DATA_SCOPE ] )
NEXT
FOR EACH n IN ::aMethods
__clsAddMsg( hClass, n[ HB_OO_MTHD_SYMBOL ], n[ HB_OO_MTHD_PFUNCTION ], ;
HB_OO_MSG_METHOD, , n[ HB_OO_MTHD_SCOPE ] )
NEXT
nClassBegin := __cls_CntClsData( hClass )
FOR EACH n IN ::aClsDatas
__clsAddMsg( hClass, n[ HB_OO_CLSD_SYMBOL ] , n:__enumIndex() + nClassBegin, ;
HB_OO_MSG_CLSACCESS, n[ HB_OO_CLSD_VALUE ], n[ HB_OO_CLSD_SCOPE ] )
__clsAddMsg( hClass, "_" + n[ HB_OO_CLSD_SYMBOL ], n:__enumIndex() + nClassBegin, ;
HB_OO_MSG_CLSASSIGN, , n[ HB_OO_CLSD_SCOPE ] )
NEXT
FOR EACH n IN ::aInlines
__clsAddMsg( hClass, n[ HB_OO_MTHD_SYMBOL ], n[ HB_OO_MTHD_PFUNCTION ], ;
HB_OO_MSG_INLINE, , n[ HB_OO_MTHD_SCOPE ] )
NEXT
FOR EACH n IN ::aVirtuals
__clsAddMsg( hClass, n, n:__enumIndex(), HB_OO_MSG_VIRTUAL )
NEXT
FOR EACH n IN ::aDelegates
__clsAddMsg( ::hClass, n[ HB_OO_DELEG_SYMBOL ], n[ HB_OO_DELEG_MESSAGE ], ;
HB_OO_MSG_DELEGATE, n[ HB_OO_DELEG_OBJECT ], ;
n[ HB_OO_DELEG_SCOPE ] )
NEXT
IF ::sOnError != NIL
__clsAddMsg( hClass, "__OnError", ::sOnError, HB_OO_MSG_ONERROR )
ENDIF
IF ::sDestructor != NIL
__clsAddMsg( hClass, "__Destructor", ::sDestructor, HB_OO_MSG_DESTRUCTOR )
ENDIF
/* Friend Classes */
FOR EACH n IN ::asFriendClass
__clsAddFriend( ::hClass, n )
NEXT
/* Friend Functions */
FOR EACH n IN ::asFriendFunc
__clsAddFriend( ::hClass, n )
NEXT
RETURN
STATIC FUNCTION Instance()
RETURN __clsInst( QSelf():hClass )
STATIC PROCEDURE AddData( cData, xInit, cType, nScope, lNoinit )
/* Default Init for Logical and numeric */
IF ! hb_defaultValue( lNoInit, .F. ) .AND. ;
cType != NIL .AND. xInit == NIL
SWITCH Asc( cType )
CASE Asc( "L" ) /* Logical */
CASE Asc( "l" ) /* Logical */
xInit := .F.
EXIT
CASE Asc( "I" ) /* Numeric or Integer */
CASE Asc( "i" ) /* Numeric or Integer */
CASE Asc( "N" ) /* Numeric or Integer */
CASE Asc( "n" ) /* Numeric or Integer */
xInit := 0
EXIT
CASE Asc( "D" ) /* Date */
CASE Asc( "d" ) /* Date */
xInit := hb_SToD()
EXIT
CASE Asc( "T" ) /* Timestamp */
CASE Asc( "t" ) /* Timestamp */
xInit := hb_SToT()
EXIT
ENDSWITCH
ENDIF
AAdd( QSelf():aDatas, { cData, xInit, cType, hb_defaultValue( nScope, HB_OO_CLSTP_EXPORTED ) } )
RETURN
STATIC PROCEDURE AddMultiData( cType, xInit, nScope, aData, lNoInit )
LOCAL cData
FOR EACH cData IN aData
IF HB_ISSTRING( cData )
QSelf():AddData( cData, xInit, cType, nScope, lNoInit )
ENDIF
NEXT
RETURN
STATIC PROCEDURE AddClassData( cData, xInit, cType, nScope, lNoInit )
/* Default Init for Logical and numeric */
IF ! hb_defaultValue( lNoInit, .F. ) .AND. ;
cType != NIL .AND. xInit == NIL
SWITCH Asc( cType )
CASE Asc( "L" ) /* Logical */
CASE Asc( "l" ) /* Logical */
xInit := .F.
EXIT
CASE Asc( "I" ) /* Numeric or Integer */
CASE Asc( "i" ) /* Numeric or Integer */
CASE Asc( "N" ) /* Numeric or Integer */
CASE Asc( "n" ) /* Numeric or Integer */
xInit := 0
EXIT
CASE Asc( "D" ) /* Date */
CASE Asc( "d" ) /* Date */
xInit := hb_SToD()
EXIT
CASE Asc( "T" ) /* Timestamp */
CASE Asc( "t" ) /* Timestamp */
xInit := hb_SToT()
EXIT
ENDSWITCH
ENDIF
AAdd( QSelf():aClsDatas, { cData, xInit, cType, ;
hb_bitOr( hb_defaultValue( nScope, HB_OO_CLSTP_EXPORTED ), ;
HB_OO_CLSTP_CLASS ) } )
RETURN
STATIC PROCEDURE AddMultiClsData( cType, xInit, nScope, aData, lNoInit )
LOCAL cData
FOR EACH cData IN aData
IF HB_ISSTRING( cData )
QSelf():AddClassData( cData, xInit, cType, nScope, lNoInit )
ENDIF
NEXT
RETURN
STATIC PROCEDURE AddInline( cMethod, bCode, nScope )
AAdd( QSelf():aInlines, { cMethod, bCode, hb_defaultValue( nScope, HB_OO_CLSTP_EXPORTED ) } )
RETURN
STATIC PROCEDURE AddMethod( cMethod, sFuncSym, nScope )
AAdd( QSelf():aMethods, { cMethod, sFuncSym, hb_defaultValue( nScope, HB_OO_CLSTP_EXPORTED ) } )
RETURN
STATIC PROCEDURE AddClsMethod( cMethod, sFuncSym, nScope )
AAdd( QSelf():aClsMethods, { cMethod, sFuncSym, ;
hb_bitOr( hb_defaultValue( nScope, HB_OO_CLSTP_EXPORTED ), ;
HB_OO_CLSTP_CLASS ) } )
RETURN
STATIC PROCEDURE AddVirtual( cMethod )
AAdd( QSelf():aVirtuals, cMethod )
RETURN
STATIC PROCEDURE AddDelegate( xMethod, cDelegMsg, cObject, nScope )
LOCAL mth
IF HB_ISSTRING( xMethod )
AAdd( QSelf():aDelegates, { xMethod, cDelegMsg, cObject, nScope } )
ELSEIF HB_ISARRAY( xMethod )
FOR EACH mth IN xMethod
AAdd( QSelf():aDelegates, { mth, cDelegMsg, cObject, nScope } )
NEXT
ENDIF
RETURN
STATIC PROCEDURE AddFriendClass( ... )
LOCAL Self := QSelf()
AEval( hb_AParams(), {| sClass | AAdd( ::asFriendClass, sClass ) } )
RETURN
STATIC PROCEDURE AddFriendFunc( ... )
LOCAL Self := QSelf()
AEval( hb_AParams(), {| sFunc | AAdd( ::asFriendFunc, sFunc ) } )
RETURN
STATIC PROCEDURE SetOnError( sFuncPtr )
QSelf():sOnError := sFuncPtr
RETURN
STATIC PROCEDURE SetDestructor( sFuncPtr )
QSelf():sDestructor := sFuncPtr
RETURN
STATIC FUNCTION InitClass()
RETURN QSelf()
Reference in New Issue View Git Blame Copy Permalink